in Makaleler

Brütten Nete 2023

Brütten Nete 2023 isimli yazımızda, Excel ile Brütten Nete maaş hesaplaması yapmak için gerekli adımlar anlatılmaktadır.

Hesaplamalarımız:

  • Kolay anlaşılması açısından Asgari Ücret değerleri ile yapılacaktır.
  • Normal SGK statüsünde çalışan kişileri kapsayan hesaplama yöntemine göre yapılacaktır.
  • Sadece Brütten Nete giden temel hesaplama kriterleri değerlerini baz alınacaktır.

İlk olarak, hesaplamamızın başlıklarını tanımlayalım:

Brütten Nete Maaş Hesaplama Başlıkları​

  1. A1 hücresine Aylar yazın,
  2. B1 hücresine Brüt Ücret yazın,
  3. C1 hücresine SGK Matrahı yazın,
  4. D1 hücresine SGK Primi yazın,
  5. E1 hücresine İŞSİZLİK Primi yazın,
  6. F1 hücresine Gelir Vergisi Matrahı yazın,
  7. G1 hücresine Kümülatif Gelir Vergisi Matrahı yazın,
  8. H1 hücresine Gelir Vergisi 1 yazın,
  9. I1 hücresine Gelir Vergisi 2 yazın,
  10. J1 hücresine Gelir Vergisi 3 yazın,
  11. K1 hücresine Gelir Vergisi 4 yazın,
  12. L1 hücresine Gelir Vergisi 5 yazın,
  13. M1 hücresine Toplam Gelir Vergisi yazın,
  14. N1 hücresine AÜ Gelir Vergisi Matrahı yazın,
  15. O1 hücresine Asgari Ücret Kümülatif Matrahı yazın,
  16. P1 hücresine AÜGV1 yazın,
  17. Q1 hücresine AÜGV2 yazın,
  18. R1 hücresine AÜGV3 yazın,
  19. S1 hücresine AÜGV4 yazın,
  20. T1 hücresine AÜGV5 yazın,
  21. U1 hücresine Toplam Asgari Ücret Gelir Vergisi yazın,
  22. V1 hücresine Kesilen Gelir Vergisi yazın,
  23. W1 hücresine Damga Vergisi Matrahı yazın,
  24. X1 hücresine Damga Vergisi yazın,
  25. Y1 hücresine Net Hakediş yazın,

Böylece, Brütten Nete Maaş Hesaplaması için bize gerekli olan başlıkları oluşturduk.

Şimdi, başlıklarımızın altına yazmamız gereken formüllere geçelim.

Brütten Nete 2023 Kullanılan Formüller​

Ay Bilgisi​

İlk olarak, A2 hücresine Ocak, A3 hücresine Şubat yazılmalıdır ve A2:A3 aralığı seçilmelidir. Daha sonra, sağ alt köşeden tutup 12 satır aşağıya çekilecektir. Böylece, Excel 12 Ay’ın isimlerini otomatik olarak yazmaktadır. Dilerseniz, ayların numaralarını da yazabilirsiniz.

Brüt Ücret Bilgisi​

1. B2:B7 hücre aralığına 10.008 rakamı yazılmalıdır. Bu rakam 2023 yılının ilk 6 aylık dilimine ait Brüt Asgari Ücrettir.

2. B8:B13 hücre aralığına da, 10.008 rakamı yazılmalıdır. Bu rakam 2023 yılının ikinci 6 aylık dilimine ait Brüt Asgari Ücrettir.

SGK Matrahı​

İlk iki bilgi, tamamen kullanıcılara dayalı ve istenilen şekilde girilen bilgi alanlarımızı oluşturmaktadır. Artık, Excel Formüllerini konuşturma işlemine başlıyoruz.

1. C2 hücresine aşağıdaki formülü yazıp, C7 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.

=EĞER(B2>75060;75060;B2)

2. C8 hücresine aşağıdaki formülü yazıp, C13 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.

=EĞER(B8>75060;75060;B8)

Böylece formüllerimiz ile yazdığımız brüt ücretin SGK Tavanından büyük olması kontrolünü sağlamış olduk.

SGK Primi​

SGK Primi hesaplaması için D2 hücresine aşağıdaki formülü yazıyoruz ve D13 hücresine kadar kopyalıyoruz.

=YUVARLA(C2*14%;2)

Bu formül bize çalışanın maaşından kesilen SGK Priminin rakamını verecektir.

İŞSİZLİK Primi​

İŞSİZLİK Primi hesaplaması için E2 hücresine aşağıdaki formülü yazıyoruz ve E13 hücresine kadar kopyalıyoruz.

=YUVARLA(C2*1%;2)

Bu formül bize çalışanın maaşından kesilen İŞSİZLİK Priminin rakamını verecektir.

Gelir Vergisi Matrahı​

Çalışanın Gelir Vergisi hesabını yapmak için, referans alınan Gelir Vergisi Matrahı formülü şu şekilde olmaktadır.

=B2-TOPLA(D2:E2)

Üstteki formülü, F2 hücresine yapıştırıp; F13 hücresine kadar kopyalamanız gerekmektedir.

Kümülatif Gelir Vergisi Matrahı​

Çalışanın Gelir Vergisi hesaplamasını yapmak için, referans alınan Kümülatif Gelir Vergisi Matrahı formülü şu şekilde olmaktadır.

=F2+EĞER(ESAYIYSA(G1);G1;0)

Üstteki formülü, G2 hücresine yapıştırıp; G13 hücresine kadar kopyalamanız gerekmektedir.

Gelir Vergisi 1​

Çalışanın maaşından kesilen %15 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((G2-F2)>=0;(G2-F2)<=70000);EĞER(G2<=70000;F2;70000-(G2-F2))*0,15;EĞER((G2-F2)<0;EĞER(VE(G2>0;G2<=70000);(G2-0)*0,15;EĞER(G2>70000;(70000-0)*0,15;0));0))

Formül, H2 hücresine yapıştırılmalıdır ve H13 hücresine kadar kopyalanmalıdır.

Gelir Vergisi 2​

Çalışanın maaşından kesilen %20 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((G2-F2)>=70000;(G2-F2)<=150000);EĞER(G2<=150000;F2;150000-(G2-F2))*0,2;EĞER((G2-F2)<70000;EĞER(VE(G2>70000;G2<=150000);(G2-70000)*0,2;EĞER(G2>150000;(150000-70000)*0,2;0));0))

Formül, I2 hücresine yapıştırılmalıdır ve I13 hücresine kadar kopyalanmalıdır.

Gelir Vergisi 3​

Çalışanın maaşından kesilen %27 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((G2-F2)>=150000;(G2-F2)<=550000);EĞER(G2<=550000;F2;550000-(G2-F2))*0,27;EĞER((G2-F2)<150000;EĞER(VE(G2>150000;G2<=550000);(G2-150000)*0,27;EĞER(G2>550000;(550000-150000)*0,27;0));0))

Formül, J2 hücresine yapıştırılmalıdır ve J13 hücresine kadar kopyalanmalıdır.

Gelir Vergisi 4​

Çalışanın maaşından kesilen %35 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((G2-F2)>=550000;(G2-F2)<=1900000);EĞER(G2<=1900000;F2;1900000-(G2-F2))*0,35;EĞER((G2-F2)<550000;EĞER(VE(G2>550000;G2<=1900000);(G2-550000)*0,35;EĞER(G2>1900000;(1900000-550000)*0,35;0));0))

Formül, K2 hücresine yapıştırılmalıdır ve K13 hücresine kadar kopyalanmalıdır.

Gelir Vergisi 5​

Çalışanın maaşından kesilen %40 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER((G2-F2)>=1900000;F2*0,4;EĞER(G2>1900000;(G2-1900000)*0,4;0))

Formül, L2 hücresine yapıştırılmalıdır ve L13 hücresine kadar kopyalanmalıdır.

Toplam Gelir Vergisi​

Üstte 5 ayrı dilimde çalışanların Gelir Vergisi hesaplamasını yaptık. Toplam Gelir Vergisi alanını ise, aynı anda birden fazla vergi dilimine giren çalışanların ilgili ay’a ait gelir vergisi toplamının ne olduğunu görmek amacıyla oluşturduk. Bunun için M2 hücresine aşağıdaki formülü yazıp, M13 hücresine kadar kopyalamanız yeterli olacaktır.

=TOPLA(H2:L2)

Brütten Nete 2023 Asgari Ücret Parametreleri​

2022 yılında değişen Maaş Hesaplama algoritması ile hayatımıza Asgari Ücret … parametreleri de girmiş oldu. Şimdi bu parametreleri küçük açıklamalar ve hesaplama formülleri ile öğretelim.

AÜ Gelir Vergisi Matrahı​

Asgari Ücret Gelir Vergisi Matrahı, çalışanın SGK Matrahının Asgari Ücreti geçip geçmemesine bağlı ve Asgari Ücret Gelir Vergisinin hesaplanması için gerekli olan alandır. Bu hesaplamayı yapmak için:

1. N2:N7 hücre aralığına aşağıdaki formülü kopyalıyoruz.

=EĞER(B2<8506,80;B2;8506,80)

2. N8:N13 hücre aralığına ise formülünüzü küçük bir değişim ile aşağıdaki gibi kopyalıyoruz.

=EĞER(B8<8506,80;B8;8506,80)

Böylece yılın iki ayrı dilimindeki net asgari ücret rakamlarını kontrol ettirerek, Asgari Ücret Gelir Vergisi Matrahı rakamı bulunmaktadır.

Asgari Ücret Kümülatif Matrahı​

Çalışanın Gelir Vergisi hesabını yapmak için, referans alınan Gelir Vergisi Matrahı formülü şu şekilde olmaktadır.

=N2+EĞER(ESAYIYSA(O1);O1;0)

Üstteki formülü, O2 hücresine yapıştırıp; O13 hücresine kadar kopyalamanız gerekmektedir.

AÜGV1​

Çalışanın maaşından kesilen %15 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((O2-N2)>=0;(O2-N2)<=70000);EĞER(O2<=70000;N2;70000-(O2-N2))*0,15;EĞER((O2-N2)<0;EĞER(VE(O2>0;O2<=70000);(O2-0)*0,15;EĞER(O2>70000;(70000-0)*0,15;0));0))

Formül, P2 hücresine yapıştırılmalıdır ve P13 hücresine kadar kopyalanmalıdır.

AÜGV2​

Çalışanın maaşından kesilen %20 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((O2-N2)>=70000;(O2-N2)<=150000);EĞER(O2<=150000;N2;150000-(O2-N2))*0,2;EĞER((O2-N2)<70000;EĞER(VE(O2>70000;O2<=150000);(O2-70000)*0,2;EĞER(O2>150000;(150000-70000)*0,2;0));0))

Formül, Q2 hücresine yapıştırılmalıdır ve Q13 hücresine kadar kopyalanmalıdır.

AÜGV3​

Çalışanın maaşından kesilen %27 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((O2-N2)>=150000;(O2-N2)<=550000);EĞER(O2<=550000;N2;550000-(O2-N2))*0,27;EĞER((O2-N2)<150000;EĞER(VE(O2>150000;O2<=550000);(O2-150000)*0,27;EĞER(O2>550000;(550000-150000)*0,27;0));0))

Formül, R2 hücresine yapıştırılmalıdır ve R13 hücresine kadar kopyalanmalıdır.

AÜGV4​

Çalışanın maaşından kesilen %35 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((O2-N2)>=550000;(O2-N2)<=1900000);EĞER(O2<=1900000;N2;1900000-(O2-N2))*0,35;EĞER((O2-N2)<550000;EĞER(VE(O2>550000;O2<=1900000);(O2-550000)*0,35;EĞER(O2>1900000;(1900000-550000)*0,35;0));0))

Formül, S2 hücresine yapıştırılmalıdır ve S13 hücresine kadar kopyalanmalıdır.

AÜGV5​

Çalışanın maaşından kesilen %40 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER((O2-N2)>=1900000;N2*0,4;EĞER(O2>1900000;(O2-1900000)*0,4;0))

Formül, T2 hücresine yapıştırılmalıdır ve T13 hücresine kadar kopyalanmalıdır.

Brütten Nete 2023 Toplam Asgari Ücret Gelir Vergisi​

Üstte 5 ayrı dilimde çalışanların Asgari Ücret Gelir Vergisi hesaplamaları yapılmıştır. Toplam Asgari Ücret Gelir Vergisi alanını ise, aynı anda birden fazla vergi dilimine giren çalışanların ilgili ay’a ait gelir vergisi toplamının ne olduğunu görmek amacıyla oluşturduk. Bunun için U2 hücresine aşağıdaki formülü yazıp, U13 hücresine kadar kopyalamanız yeterli olacaktır.

=TOPLA(P2:T2)

Kesilen Gelir Vergisi​

Artık, bu aşamada çalışanın maaşından kesilen işleme konu Gelir Vergisinin hesaplanmasına geçebiliriz. Bunun için, V2 hücresine aşağıdaki formülü yazıp, V13 hücresine kadar çoğaltıyoruz.

=YUVARLA(EĞER(M2-U2<=0;0;M2-U2);2)

Damga Vergisi Matrahı​

2022 yılının değişen maaş algoritmalarının etkilediği bir diğer husus ise Damga Vergisi oldu. Çalışanların maaşlarından Brüt Asgari Ücret kadar rakam damga vergisi hesaplamasından muaf edilmektedir. Böylece, Damga Vergisi hesaplamasını yapabilmemiz için gerekli olan Damga Vergisi Matrahı hesabını şu şekilde yapmaktayız.
1. W2 hücresine aşağıdaki formülü yazıyoruz ve W7 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.

=EĞER(B2<=0;10008;B2-10008)

2. W8 hücresine aşağıdaki formülü yazıyoruz ve W13 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.

=EĞER(B8<=0;10008;B8-10008)

Damga Vergisi​

Çalışanın maaşından kesmemiz gereken Damga Vergisini hesaplamak için X2 hücresine aşağıdaki formülü yazıyoruz ve X18 hücresine kadar yapıştırıyoruz.

=YUVARLA(W2*0,759%;2)

Net Hakediş​

Ve artık noktayı koyma zamanı…Adım adım hesaplamalarımız neticesinde, Brüt Ücretimizden kesilen toplam 4 ana kalem vergisini düşerek çalışanın eline geçecek olan Net Hakediş rakamını bulunmalıdır. Yani, Y2 hücresine aşağıdaki formülü yazılmalıdır ve Y13 hücresine kadar kopyalanmalıdır.

=B2-D2-E2-V2-X2

Brütten Nete 2023 Sonuç​

Artık, siz de kolayca bu formülleri kullanarak temel düzeyde bir maaş hesaplamasının nasıl yapıldığını öğrenebilirsiniz. Bu hesaplamadaki formüller, maaş hesabının en zor aşamalarından biri olan Gelir Vergisi hesaplamalarını da sorunsuzca yapmanızı sağlayacaktır.

Eğer, Excel formüllerine biraz aşinaysanız; Gelir Vergisi hesabının nasıl yapıldığının mantığını da rahatça anlayabilirsiniz. Dilerseniz, Netten Brüte hesaplama işlemlerini anlattığımız makalemizi de inceleyebilirsiniz.

Bir yanıt yazın

E-posta adresiniz yayınlanmayacak. Gerekli alanlar * ile işaretlenmişlerdir