Excel İNDİS İşlevi

Excel İNDİS İşlevi, 2003 versiyonu ile yayınlanan Arama ve Başvuru kategorisinin güçlü sonuçlar üreten fonksiyonlarındandır.

Excel İNDİS İşlevi Açıklamalar

Konuma göre bir listede veya tabloda bir değer bulmayı sağlamaktadır. Bir aralıkta veya dizide belirli bir konumdaki değeri döndürmektedir. İNDİS güçlü ve çok yönlü bir işlevdir ve tek tek değerleri veya tüm satırları ve sütunları almak için kullanılmaktadır. Sıklıkla, KAÇINCI İşleviyle birlikte kullanılır. Bu ortalıkta, KAÇINCI İşlevi bir konumu bulur ve İNDİS İşlevini besler. Böylece, dizin bu konumdaki değeri döndürmektedir.

Diziliş Yapısı – Türkçe Diziliş

=İNDİS(başv; satır_sayısı; [sütun_sayısı]; [alan_sayısı])
=İNDİS(dizi; satır_sayısı; [sütun_sayısı])

Diziliş Yapısı – İngilizce Diziliş

=INDEX(array; row_num; [col_num]; [area_num])
=INDEX(array; row_num; [col_num])

Fonksiyon Öğeleri

Aşağıda, İNDİS Fonksiyonunun iki ayrı kullanım öğesi bulunmaktadır. İlk olarak aşağıdaki gibi öğeleri görebilirsiniz.

başv: Bir hücre aralığı veya bir dizi sabiti.
satır_sayısı: Referans veya dizideki satır konumu.
[sütun_sayısı] – Opsiyonel: Başvuru veya dizideki sütun konumu.
[alan_sayısı] – Opsiyonel: Kullanılması gereken referans aralığı.

İkinci olarak ise, aşağıdaki öğeleri görebilirsiniz.

dizi: Bir hücre aralığı veya bir dizi sabiti.
satır_sayısı: Referans veya dizideki satır konumu.
[sütun_sayısı] – Opsiyonel: Başvuru veya dizideki sütun konumu.

İngilizce Adı

INDEX

Yayınlandığı Versiyon

Excel 2003

Destekleyen Versiyonlar

Excel 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007, Excel 2003

Benzer ve Birlikte Kullanıldığı Bazı Fonksiyonlar

Benzer

DÜŞEYARA, YATAYARA, ÇAPRAZARA, ÇAPRAZEŞLEŞTİR, FİLTRE

Birlikte Kullanıldığı

KAÇINCI: Belirli bir sırayla belirtilen bir değerle eşleşen bir dizideki bir öğenin göreli konumunu döndürmektedir.

İNDİS İşlevini Kullanırken Karşılaşılan Hatalar

#BAŞV! hatası aşağıdaki durumlarda iade edilecektir:
satır_sayısı, [sütun_sayısı] ve [alan_sayısı], başvuru içinde bir hücreye işaret etmez;
satır_sayısı bağımsız değişkeni, tanımlanan aralıktaki satırlardan daha büyük.
[sütun_sayısı] bağımsız değişkeni, tanımlanan aralıktaki sütun sayısından daha büyük.
Alan bağımsız değişkenleri, tanımlanan alan sayısını aşmaktadır.
#DEĞER! hatası satır_sayısı, [sütun_sayısı] veya [alan_sayısı] için sayısal olmayan bağımsız değişkenler verilirse döndürmektedir.

Excel İNDİS İşlevi Kullanım Örnekleri

Burada, Excel İNDİS işlevinin daha iyi anlaşılması adına örnek uygulamalar yer almaktadır.

Bir Satırdan ve Sütundan Öğe Seçimi

İlk olarak, üstteki resimde veri aralığımıza ait tanımlamaları yazalım. Veriler, D4:G9 aralığındadır. Üstte, mavi renkli alanlar İNDİS’in “[sütun_sayısı]” öğesinde kullanılan alanlardır. Soldaki sarı renkli alanlarsa, İNDİS’in “satır_sayısı” öğesinde kullanılan alanlardır. “satır_sayısı” öğesinin referans alınacağı 2 değeri, J3 hücresinde konumlandırılmaktadır. Böylece, sonuca ulaşmak için kullanacağımız formül şu şekilde olmaktadır.

=İNDİS(D4:D9;J3)

Gördüğünüz üzere, formül D sütunundaki ilgili hücre aralıklarına uygulanmıştır. Eğer, sütun değil, satır sayısını aramak isterseniz, formülü aşağıdaki gibi değiştirmeniz yeterli olacaktır.

=İNDİS(D5:G5;;J6)

Böylece, işlevin “satır_sayısı” öğesi boş geçilmiş ve “[sütun_sayısı]” öğesine geçilmiştir.

Kesişen Alandan Öğe Seçimi

Öncelikle, kesişen alandan öğe seçmek için iki ayrı bilgiye ihtiyaç bulunmaktadır. Bunlar, satır ve sütun sayılarını ifade etmektedir. Bu tanımlamanın yapılmasından sonra, kesişen hücredeki sonucu bulmak için aşağıdaki formül yeterli olacaktır.

=İNDİS(D4:G9;J3;J4)

İlk olarak, formüldeki satır ve sütun sayılarının bulunması için “dizi” öğesi genişletilmiştir. Daha sonra, alınması istenen satır ve sütun sayıları için ilgili hücrelere tanımlama yapılmıştır. Böylece, dizi aralığındaki 2. satır ve 3. sütundaki kesişen M değeri bulunmuştur.

Bir Tablodan Tüm Bir Satırın veya Sütunun Seçilmesi

Burada, belirlenen bir satır sayısını referans alan bir formül örneği ele alınmaktadır. Lakin, kullandığınız Excel versiyonuna göre dikkat edilmesi gereken ince detaylar vardır. Öncelikle, Excel 365 kullanıcısı değilseniz, formülü uygulamadan önce formülün olduğu alanı seçmeniz gerekmektedir.

Böylece, oluşan dizi için ilk aşama gerçekleşecektir. Bundan sonra üstteki formül çubuğuna aşağıdaki formülü yazmanız yeterli olacaktır.

=İNDİS(D4:G9;C12;0)

ÖNEMLİ NOT: Burada formülü bitirmek için Enter değil Ctrl + Shift + Enter tuşlarına basmanız gerekmektedir. Dizinin oluşması için bu gerekli bir adımdır. Eğer, bu işlemi yapmazsanız, #DEĞER! Hatası alınacaktır. Ayrıca, “[sütun_sayısı]” öğesine de mutlaka 0 değeri girilmelidir. Aksi halde, #BAŞV! hatası alınacaktır.

Ancak, Ctrl + Shift + Enter tuşlarına basarsanız istenilen dizinin doldurulduğunu göreceksiniz. Formülünüzün başında ve sonunda {} işaretleri olduğunu göreceksiniz.

DİKKAT! Bu dizideki formülü silmek isterseniz, Excel size izin vermeyecektir 🙂 Silmeniz için önce tüm diziyi seçmeniz elzemdir!

Aynı şekilde, sütunlarında bir dizi oluşturmasını istiyorsanız, bu seferde dizinin oluşacağı sütunları seçmelisiniz.

Böylece, formülümüzün çalışması için ilk adım atılmış olmaktadır. Hemen akabinde, sonucu listelemek için aşağıdaki formül kullanılacaktır.

=İNDİS(D4:G9;;J3)

Barada da, aynen satır için uygulalan Ctrl + Shift + Enter tuşlarına basılması elzemdir.

Eğer, Excel 365 versiyonuna sahipseniz o zaman üstte anlattıklarımızın hiç birine ihtiyaç olmamaktadır. Excel 365’in dinamik özelliği sayesinde, formül otomatik olarak taşma aralığı oluşturacaktır. Ancak, oluşan taşma aralığının sonuç vermesi için, formülün sağında ve altında bulunan hücrelerin boş olması gerekir. Aksi halde, formül taşma hatası verecektir.

Excel İNDİS İşlevi Referans Formu

Burada, iki ayrı tablodan istenilen sonucun nasıl elde edileceği öğretilmektedir. Üstte gördüğünüz üzere, benzer yapılı iki ayrı tablo bulunmaktadır. Altta ise, tablo, satır ve sütun numaraları belirtilmiştir. Böylece, sonuca ulaşmamız için kullanılacak olan formül şu şekilde olacaktır.

=İNDİS((D4:G9;D13:E18);D21;D22;D20)

KAÇINCI ile Birlikte Kullanılması

İNDİS’in gerektirdiği satır veya sütun numaralarını otomatik olarak bulmak için, KAÇINCI fonksiyonuna ihtiyaç duyulmaktadır.

Üst resimde göreceğiniz üzere, Adı bilgisi “Veli” olarak yazılmıştır. Yapmak istediğimiz, İNDİS ile Veli’ye ait Beden bilgisini bulmaktır. Ancak, İNDİS’te “aranan değer” tarzı bir öğe bulunmamaktadır. Dolayısıyla, “Veli” olarak yazılmış adı bilgisinin olduğu satır sayısını bulmaya ihtiyacımız bulunmaktadır. Bunun için KAÇINCI fonksiyonu şu şekilde yazılmaktadır.

KAÇINCI(J3;D4:D9;0)

Böylece, J3 hücresinde yazılı olan Veli ismi, D4:D9 aralığında tam eşleşme şeklinde aranacaktır. Bulunan değer, 2 şeklinde olmaktadır. Yani bu değer, İNDİS’in “satır_sayısı” öğesidir. Geriye kalan, Beden bilgisinin olduğu sütunun numarasının bulunmasıdır. Beden bilgisini sürekli sabit bir değer şeklinde arayacaksak, bunun için bir formül kullanmamıza gerek olmaz. Yani, dizinin kaçıncı sütunundaysa, o numarayı yazmanız yeterli olacaktır. Lakin, aranan sütun ismi, aranacak olan sütun isimleri içinde yer alyorsa, o zaman bunun içinde KAÇINCI kullanılabilir. Formül şu şekilde olmaktadır.

KAÇINCI(I4;D3:G3;0)

I4 hücresinde yer alan Beden bilgisi, başlık satırında aranacak ve “[sütun_sayısı]” öğesi 3 olarak döndürülecektir. Böylece, İNDİS için gerekli olan satır ve sütun numaralarını bulmaktayız. Sonuç olarak, formülümüzün tamamı şu şekilde olmaktadır.

=İNDİS(D4:G9;KAÇINCI(J3;D4:D9;0);KAÇINCI(I4;D3:G3;0))

Gördüğünüz üzere, İNDİS’in hem satır hem de sütun sayılarını KAÇINCI ile dinamik hale getirdik. Ancak, her seferinde KAÇINCI kullanmanıza gerek yoktur. Bu duruma gerek olup olmadığına, kullanıcılar tablo yapılarına göre karar vermelidir. Böylece, Excel İNDİS işlevinin temel kullanımına dair tüm detayları ele almış olduk. Bu yararlı işlevi aramalarınızda mutlaka kullanmanızı tavsiye ederiz.